Export e-maily z Entourage do aplikace Outlook

Článek Dave Addey

Nedávno jsem měl exportovat spoustu e-mailů od Entourage a do aplikace Outlook, aby jim poslat někoho v podobě, kterou lze procházet a číst na PC. Člověk by si myslel, že export výběr emailů z jednoho řídícího email nástroj Microsoft do jiného by bylo snadné, že jo? bohužel ne. díkybohu, trochu AppleScriptu a relativně levný nástroj dostal věci pracovat pro mě. Tento příspěvek popisuje, jak.

Hlavním problémem je nedostatek společného formátu mezi Entourage (.mbox pro složky, .eml pro jednotlivé e-maily) a Outlook (.pst za všechno). Tam použitý být opravdu dobrý AppleScript export nástroj pro export z aplikace Entourage, ale bohužel to nikdy nebyl aktualizován pro práci na Leopard. Můžete exportovat celou složku jako soubor MBOX z Entourage, ale tyto doby nemohou být otevřeny Outlook a proto nejsou k ničemu buď.

(Jako stranou, existuje mnoho způsobů, jak jít jiný cesta, exportovat z aplikace Outlook a importovat do Entourage. Je to skoro, jako by spousta lidí, kteří přecházejí z PC na Mac, ale jen málo je třeba jít v opačném směru ...)

Můj konečný roztok má dvě části - dostat maily z Entourage, a pak ji dostat do Outlooku.

Získání pošty z Entourage

Pro tuto část, Napsal jsem AppleScriptu (silně založené na kódu z macosxhints) exportovat všechny aktuálně vybrané e-maily v aplikaci Entourage do složky v počítači Mac. Mnohé díky macosxhints uživatelské golgi_body pro vysílání původní kód.

Zde je scénář, že jsem pomocí (kopírovat to do editoru skriptů jej používat):

tell application "Microsoft Entourage"
    -- get a reference to all selected messages from entourage
    set selectedMessages to the current messages
    if selectedMessages is {} then
        return
    end if

    -- absolute reference to our export folder
    set fpath to "DiskName:Users:myusername:Documents:existingfolder:"

    repeat with i in selectedMessages

        set sentDate to time sent of i
        set fname to fpath ¬
            & my padNumber(year of sentDate as integer) ¬
            & "-" & my padNumber(month of sentDate as integer) ¬
            & "-" & my padNumber(day of sentDate as integer) ¬
            & "-" & my padNumber(hours of sentDate as integer) ¬
            & "-" & my padNumber(minutes of sentDate as integer) ¬
            & "-" & my padNumber(seconds of sentDate as integer) ¬

        tell application "Finder"
            if (exists file (fname & ".eml")) then
                set k to 1
                repeat while (exists file (fname & "-" & (k as string) & ".eml"))
                    set k to k + 1
                end repeat
                set fname to (fname & "-" & (k as string))
            end if
        end tell

        set fname to fname & ".eml"
        save i in fname
        tell application "Finder" to update file fname

    end repeat

end tell

to padNumber(theNumber)
    if theNumber is less than 10 then
        return "0" & theNumber
    else
        return theNumber
    end if
end padNumber

Budete muset nastavit fpath být cestu k existující složky na počítači Macintosh. Spustíte-li tento skript v Script Editor, všechny vybrané soubory v Entourage budou exportovány do svého exportu složky jako EML soubory.

Proč používat AppleScriptu vůbec? Proč ne jen přetáhnout vybrané e-maily na složku? Po všem, Tento vyzve Entourage jim export se v EML formátu. Problém je v tom, pokud tak učiníte, Entourage exportuje e-maily pomocí e-mailu předmět jako název souboru. To může obsahovat všechny druhy podivných a úžasných postav, a Windows nemá rád, že vůbec. Tento skript zabrání problém úplně pomocí datum a čas, kdy byl e-mail odeslán jako jméno souboru. (To také usnadňuje objednejte si eml soubory podle data a času ve Finderu, pokud potřebujete.)

Získání pošty v aplikaci Outlook

Pro tuto část, Použil jsem nástroj Windows nazývaný Průvodce importem aplikace Outlook. To stojí $19.95, ale je to víc než to stojí za to, když vezmete v úvahu čas, který může ušetřit. Můžete si ji stáhnout a vyzkoušet zdarma (max 5 e-mailů za demo dovozu), ale pozor - v demo módu, nelze zapnout „umožnit EML předzpracování (UNIX, MAC)“Možnost, aby Průvodce rozpoznat Mac kódované emaily, a tak importované e-maily budou obsahovat velké množství „=“ symbol při zobrazení v aplikaci Outlook. Dobrou zprávou je, že zakoupené aplikace funguje s Mac kódované e-maily.

Proces importu je docela snadné. Na počítači s nainstalovanou aplikaci Outlook, propracovat Průvodci importem Outlook, přičemž nezapomeňte zapnout „Povolit EML předzpracování (UNIX, MAC)"možnost (najdete pod tlačítkem „Volby“ na „Vyberte zdrojovou složku“ obrazovce) aby se ujistil, že vaše Mac-kódované emaily jsou uznány. Průvodce je docela samo-vysvětlující, a jsou Úplné instrukce on-line, takže nebudu běžet přes zbytek nastavení podrobně zde. Bude to chvíli trvat, než dělat import, ale nakonec skončíte se všemi svými e-maily v aplikaci Outlook, se všemi přílohami a původní záhlaví.

Já jsem jen sám se pokusil tento proces Entourage 2008 (Leopard) a Outlook 2002 (na XP), ale já bych očekávat, že bude pracovat s dřívějších verzích aplikace Entourage příliš. Průvodce Outlook importem tvrdí, že pracuje na Windows 98 / Me / NT 4.0 / 2000 / XP / 2003 s Outlookem 98/2000/2002/2003/2007, takže byste měli být dobré jít bez ohledu na to, jaké jsou vaše nastavení.